Bajdi electronics

Arduino: wireless contol of 2 stepper motors from Bajdi on Vimeo.

A month ago I wrote a sketch to control 2 little stepper motors with an analog joystick. After getting the Nrf24L01 modules to work last week I wanted to connect the joystick to one Arduino and the stepper motors to another Arduino. It was easier then I thought, I just put the 2 analog values from the joystick in an array. Then we can sent that array to the other Arduino and that’s about it 🙂 I connected the little 28YBJ-48 stepper motors to my Arduino Mega 2560 and the joystick to my Uno. As you can see in the video I’m using 2 different Nrf24L01 modules, the one connected to the Mega 2560 has a preamp and amp the one connected to the Uno is the small version with integrated antenna. I have 2 of each of these modules, but I seemed to have blown one up. I mistakenly connected 5V to one of the small modules and it’s dead 🙁 Already ordered a couple of new ones on Ebay 🙂 Luckily it was only a small module, I paid 20$ a piece for the big modules with preamp and amp, I’m NOT going to blow those up.
Here is the code I used:

Transmitter code:

<pre>// http://www.bajdi.com
// Nrf24L01 connected to Arduino Uno
// Nrf24L01 connection details http://arduino-info.wikispaces.com/Nrf24L01-2.4GHz-HowTo
// Transmit analog values from joystick to the receiver

#include <SPI.h>
#include <Mirf.h>
#include <nRF24L01.h>
#include <MirfHardwareSpiDriver.h>

int joystick[2];

void setup(){

  Serial.begin(9600);
  Mirf.spi = &MirfHardwareSpi;
  Mirf.init();
  Mirf.setRADDR((byte *)"clie1");
  Mirf.payload = sizeof(joystick);
  Mirf.config();
}

void loop(){
  joystick[0] = analogRead(A0);
  joystick[1] = analogRead(A1);
  Serial.println(joystick[0]);
  Serial.println(joystick[1]);

  Mirf.setTADDR((byte *)"serv1");

  Mirf.send((byte *) &joystick);

  while(Mirf.isSending()){
  }
}

Receiver code:

// http://www.bajdi.com
// Nrf24L01 connected to Arduino Mega 2560
// Nrf24L01 connection details http://arduino-info.wikispaces.com/Nrf24L01-2.4GHz-HowTo
// Receives analog values (joystick) from transmitter and moves stepper motors left/right forward/backward

#include <SPI.h>
#include <Mirf.h>
#include <nRF24L01.h>
#include <MirfHardwareSpiDriver.h>
#include <Stepper.h>

const int stepsPerRevolution = 64;

Stepper small_stepper(stepsPerRevolution, 8,10,9,11);
Stepper small_stepper2(stepsPerRevolution, 4,6,5,7);

int joystick[2];

void setup(){

  small_stepper.setSpeed(250);    // set first stepper speed
  small_stepper2.setSpeed(250);   // set second stepper speed
  Mirf.cePin = 48;             //ce pin on Mega 2560
  Mirf.csnPin = 49;            //csn pin on Mega 2560
  Mirf.spi = &MirfHardwareSpi;
  Mirf.init();
  Mirf.setRADDR((byte *)"serv1");
  Mirf.payload = sizeof(joystick);
  Mirf.config();
}

void loop(){

  while(!Mirf.dataReady()){
  }
  Mirf.getData((byte *) &joystick);

  if (joystick[0] < 490) {
    small_stepper.step(1);
  }   // step forward
  if (joystick[0] > 540) {
    small_stepper.step(-1);
  }  // step backward

  if (joystick[1] < 490) {
    small_stepper2.step(1);
  } // step left
  if (joystick[1] > 540) {
    small_stepper2.step(-1);
  } // step right
}